definition-tree.lisp 4.57 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131
;;
;; Copyright 2002, 2009, 2012 Genworks International and Genworks BV 
;;
;; This source file is part of the General-purpose Declarative
;; Language project (GDL).
;;
;; This source file contains free software: you can redistribute it
;; and/or modify it under the terms of the GNU Affero General Public
;; License as published by the Free Software Foundation, either
;; version 3 of the License, or (at your option) any later version.
;; 
;; This source file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; Affero General Public License for more details.
;; 
;; You should have received a copy of the GNU Affero General Public
;; License along with this source file.  If not, see
;; <http://www.gnu.org/licenses/>.
;; 


(in-package :gdlxml)

(define-object definition-tree ()
  
  :documentation (:description "Given a symbol naming a GDL object which is already defined in the system,
this object generates a tree of all the message categories and all the messages within each category.

This tree can then be used as the basis for generating a representation of the object definition in 
an external format, such as GDLXML.")
  
  
  :input-slots (name-symbol)

  :computed-slots ((strings-for-display (format nil "Definition for ~s" (the name-symbol)))
		   
		   
		   (object-package (symbol-package (the name-symbol)))
		   
		   (object-documentation (the canonical-instance documentation))
		   
		   (class (find-class (the name-symbol)))
		   
		   (canonical-instance (make-object (the name-symbol)))
		   
		   ;;
		   ;; FLAG -- message-data should be defined on the meta-class (gdl-class).
		   ;;
		   (message-data (the canonical-instance (message-list :category :all
								       :message-type :local 
								       :return-category? t
								       :sort-order :by-category)))
		   
		   
		   ;;
		   ;; FLAG -- mixin-data should be defined on the meta-class (gdl-class).
		   ;;
		   (mixin-data (the canonical-instance (mixins :local? t)))
		   
		   (message-section-ht (let ((ht (make-hash-table)))
					 (mapc #'(lambda(message section) (push message (gethash section ht)))
					       (plist-keys (the message-data)) (plist-values (the message-data))) ht)))

  
  :trickle-down-slots (canonical-instance name-symbol)
  
  :objects ((sections :type 'message-section 
		      :sequence (:size (hash-table-count (the message-section-ht)))
		      :plist (list-hash (the message-section-ht))
		      :name (nth (the-child index) (plist-keys (the-child plist)))
		      :keys (nth (the-child index) (plist-values (the-child plist))))))

(define-object message-section ()
  
  :input-slots (name keys)
  
  :computed-slots ((strings-for-display (format nil "~a" (the name)))
		   
		   
		   
		   (section-key-and-modifiers
		    (ecase (the name)
		      (:required-input-slots (list :input-slots))
		      (:optional-input-slots (list :input-slots))
		      (:settable-optional-input-slots (list :input-slots :settable))
		      (:defaulted-input-slots (list :input-slots :defaulting))
		      (:settable-defaulted-input-slots (list :input-slots :settable :defaulting))
		      (:computed-slots (list :computed-slots))
		      (:settable-computed-slots (list :computed-slots :settable))
		      (:uncached-computed-slots (list :computed-slots :uncached))
		      (:objects (list :objects))
		      (:quantified-objects (list :objects))
		      (:hidden-objects (list :hidden-objects))
		      (:quantified-hidden-objects (list :hidden-objects))
		      (:functions (list :functions)))))
  
  
  :objects ((messages :type 'message 
		      :category (the name)
		      :sequence (:size (length (the keys)))
		      :section-key (first (the section-key-and-modifiers))
		      :modifiers (rest (the section-key-and-modifiers))
		      :key (nth (the-child index) (the keys)))))



(define-object message ()
  :input-slots (section-key category key modifiers)
  
  :computed-slots ((strings-for-display (format nil "~a" (the key)))
		   
		   (source-list (let ((source-list (the canonical-instance (slot-source (the key)))))
				  (when (eql (first source-list) (the name-symbol)) (second source-list))))

		   
		   (source-code-body (case (the category) 
				       (:functions (second (the source-list)))
				       (otherwise (the source-list))))
		   
		   
		   (source-code-argument-list (case (the category)
						(:functions (first (the source-list)))
						(otherwise nil)))
		   
		   
		   (remark-string (getf (the canonical-instance (slot-documentation (the key)))
					(the name-symbol)))))