source-registry.lisp 16.7 KB
Newer Older
1 2 3 4
;;;; -----------------------------------------------------------------
;;;; Source Registry Configuration, by Francois-Rene Rideau
;;;; See the Manual and https://bugs.launchpad.net/asdf/+bug/485918

5
(uiop/package:define-package :asdf/source-registry
6
  (:recycle :asdf/source-registry :asdf)
7
  (:use :uiop/common-lisp :uiop :asdf/upgrade :asdf/find-system)
8
  (:export
9
   #:*source-registry-parameter* #:*default-source-registries*
10
   #:invalid-source-registry
11
   #:source-registry-initialized-p
12
   #:initialize-source-registry #:clear-source-registry #:*source-registry*
13
   #:ensure-source-registry #:*source-registry-parameter*
14 15
   #:*default-source-registry-exclusions* #:*source-registry-exclusions*
   #:*wild-asd* #:directory-asd-files #:register-asd-directory
16
   #:*recurse-beyond-asds* #:collect-asds-in-directory #:collect-sub*directories-asd-files
17 18
   #:validate-source-registry-directive #:validate-source-registry-form
   #:validate-source-registry-file #:validate-source-registry-directory
19 20
   #:parse-source-registry-string #:wrapping-source-registry
   #:default-user-source-registry #:default-system-source-registry
21 22
   #:user-source-registry #:system-source-registry
   #:user-source-registry-directory #:system-source-registry-directory
23
   #:environment-source-registry #:process-source-registry #:inherit-source-registry
24
   #:compute-source-registry #:flatten-source-registry
25
   #:sysdef-source-registry-search))
26 27
(in-package :asdf/source-registry)

28 29 30
(with-upgradability ()
  (define-condition invalid-source-registry (invalid-configuration warning)
    ((format :initform (compatfmt "~@<Invalid source registry ~S~@[ in ~S~]~@{ ~@?~}~@:>"))))
31

32
  ;; Default list of directories under which the source-registry tree search won't recurse
33
  (defvar *default-source-registry-exclusions*
34 35
    '(;;-- Using ack 1.2 exclusions
      ".bzr" ".cdv"
36 37 38
      ;; "~.dep" "~.dot" "~.nib" "~.plst" ; we don't support ack wildcards
      ".git" ".hg" ".pc" ".svn" "CVS" "RCS" "SCCS" "_darcs"
      "_sgbak" "autom4te.cache" "cover_db" "_build"
39 40
      ;;-- debian often builds stuff under the debian directory... BAD.
      "debian"))
41

42
  ;; Actual list of directories under which the source-registry tree search won't recurse
43
  (defvar *source-registry-exclusions* *default-source-registry-exclusions*)
44

45
  ;; The state of the source-registry after search in configured locations
46 47
  (defvar *source-registry* nil
    "Either NIL (for uninitialized), or an equal hash-table, mapping
48 49
system names to pathnames of .asd files")

50 51
  ;; Saving the user-provided parameter to the source-registry, if any,
  ;; so we can recompute the source-registry after code upgrade.
52 53
  (defvar *source-registry-parameter* nil)

54 55 56 57 58 59 60 61 62 63
  (defun source-registry-initialized-p ()
    (typep *source-registry* 'hash-table))

  (defun clear-source-registry ()
    "Undoes any initialization of the source registry."
    (setf *source-registry* nil)
    (values))
  (register-clear-configuration-hook 'clear-source-registry)

  (defparameter *wild-asd*
64
    (make-pathname :directory nil :name *wild* :type "asd" :version :newest))
65 66 67 68 69

  (defun directory-asd-files (directory)
    (directory-files directory *wild-asd*))

  (defun collect-asds-in-directory (directory collect)
70 71 72 73 74 75 76 77
    (let ((asds (directory-asd-files directory)))
      (map () collect asds)
      asds))

  (defvar *recurse-beyond-asds* t
    "Should :tree entries of the source-registry recurse in subdirectories
after having found a .asd file? True by default.")

78 79
  ;; When walking down a filesystem tree, if in a directory there is a .cl-source-registry.cache,
  ;; read its contents instead of further recursively querying the filesystem.
80 81 82 83 84 85
  (defun process-source-registry-cache (directory collect)
    (let ((cache (ignore-errors
                  (safe-read-file-form (subpathname directory ".cl-source-registry.cache")))))
      (when (and (listp cache) (eq :source-registry-cache (first cache)))
        (loop :for s :in (rest cache) :do (funcall collect (subpathname directory s)))
        t)))
86 87

  (defun collect-sub*directories-asd-files
88 89
      (directory &key (exclude *default-source-registry-exclusions*) collect
                   (recurse-beyond-asds *recurse-beyond-asds*) ignore-cache)
90
    (let ((visited (make-hash-table :test 'equalp)))
91 92 93 94 95 96 97 98 99 100 101 102 103
      (flet ((collectp (dir)
               (unless (and (not ignore-cache) (process-source-registry-cache directory collect))
                 (let ((asds (collect-asds-in-directory dir collect)))
                   (or recurse-beyond-asds (not asds)))))
             (recursep (x)                    ; x will be a directory pathname
               (and
                (not (member (car (last (pathname-directory x))) exclude :test #'equal))
                (flet ((pathname-key (x)
                         (namestring (truename* x))))
                  (let ((visitedp (gethash (pathname-key x) visited)))
                    (if visitedp nil
                        (setf (gethash (pathname-key x) visited) t)))))))
      (collect-sub*directories directory #'collectp #'recursep (constantly nil)))))
104

105 106 107

  ;;; Validate the configuration forms

108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134
  (defun validate-source-registry-directive (directive)
    (or (member directive '(:default-registry))
        (and (consp directive)
             (let ((rest (rest directive)))
               (case (first directive)
                 ((:include :directory :tree)
                  (and (length=n-p rest 1)
                       (location-designator-p (first rest))))
                 ((:exclude :also-exclude)
                  (every #'stringp rest))
                 ((:default-registry)
                  (null rest)))))))

  (defun validate-source-registry-form (form &key location)
    (validate-configuration-form
     form :source-registry 'validate-source-registry-directive
          :location location :invalid-form-reporter 'invalid-source-registry))

  (defun validate-source-registry-file (file)
    (validate-configuration-file
     file 'validate-source-registry-form :description "a source registry"))

  (defun validate-source-registry-directory (directory)
    (validate-configuration-directory
     directory :source-registry 'validate-source-registry-directive
               :invalid-form-reporter 'invalid-source-registry))

135 136 137

  ;;; Parse the configuration string

138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158
  (defun parse-source-registry-string (string &key location)
    (cond
      ((or (null string) (equal string ""))
       '(:source-registry :inherit-configuration))
      ((not (stringp string))
       (error (compatfmt "~@<Environment string isn't: ~3i~_~S~@:>") string))
      ((find (char string 0) "\"(")
       (validate-source-registry-form (read-from-string string) :location location))
      (t
       (loop
         :with inherit = nil
         :with directives = ()
         :with start = 0
         :with end = (length string)
         :with separator = (inter-directory-separator)
         :for pos = (position separator string :start start) :do
           (let ((s (subseq string start (or pos end))))
             (flet ((check (dir)
                      (unless (absolute-pathname-p dir)
                        (error (compatfmt "~@<source-registry string must specify absolute pathnames: ~3i~_~S~@:>") string))
                      dir))
159
               (cond
160 161 162 163 164 165 166 167
                 ((equal "" s) ; empty element: inherit
                  (when inherit
                    (error (compatfmt "~@<Only one inherited configuration allowed: ~3i~_~S~@:>")
                           string))
                  (setf inherit t)
                  (push ':inherit-configuration directives))
                 ((string-suffix-p s "//") ;; TODO: allow for doubling of separator even outside Unix?
                  (push `(:tree ,(check (subseq s 0 (- (length s) 2)))) directives))
168
                 (t
169 170 171 172 173 174 175 176 177 178 179 180 181 182 183
                  (push `(:directory ,(check s)) directives))))
             (cond
               (pos
                (setf start (1+ pos)))
               (t
                (unless inherit
                  (push '(:ignore-inherited-configuration) directives))
                (return `(:source-registry ,@(nreverse directives))))))))))

  (defun register-asd-directory (directory &key recurse exclude collect)
    (if (not recurse)
        (collect-asds-in-directory directory collect)
        (collect-sub*directories-asd-files
         directory :exclude exclude :collect collect)))

184
  (defparameter* *default-source-registries*
185 186 187
    '(environment-source-registry
      user-source-registry
      user-source-registry-directory
188
      default-user-source-registry
189 190
      system-source-registry
      system-source-registry-directory
191 192
      default-system-source-registry)
    "List of default source registries" "3.1.0.102")
193

194 195
  (defparameter *source-registry-file* (parse-unix-namestring "common-lisp/source-registry.conf"))
  (defparameter *source-registry-directory* (parse-unix-namestring "common-lisp/source-registry.conf.d/"))
196 197 198

  (defun wrapping-source-registry ()
    `(:source-registry
Francois-Rene Rideau's avatar
Francois-Rene Rideau committed
199
      #+(or clasp ecl sbcl) (:tree ,(resolve-symlinks* (lisp-implementation-directory)))
200
      :inherit-configuration
201
      #+mkcl (:tree ,(translate-logical-pathname "SYS:"))
202
      #+cmucl (:tree #p"modules:")
203
      #+scl (:tree #p"file://modules/")))
204
  (defun default-user-source-registry ()
205
    `(:source-registry
206 207
      (:tree (:home "common-lisp/"))
      #+sbcl (:directory (:home ".sbcl/systems/"))
208 209
      (:directory ,(xdg-data-home "common-lisp/systems/"))
      (:tree ,(xdg-data-home "common-lisp/source/"))
210 211 212
      :inherit-configuration))
  (defun default-system-source-registry ()
    `(:source-registry
213
      ,@(loop :for dir :in (xdg-data-dirs "common-lisp/")
214 215
              :collect `(:directory (,dir "systems/"))
              :collect `(:tree (,dir "source/")))
216 217
      :inherit-configuration))
  (defun user-source-registry (&key (direction :input))
218
    (xdg-config-pathname *source-registry-file* direction))
219
  (defun system-source-registry (&key (direction :input))
220
    (find-preferred-file (system-config-pathnames *source-registry-file*)
221
                         :direction direction))
222
  (defun user-source-registry-directory (&key (direction :input))
223
    (xdg-config-pathname *source-registry-directory* direction))
224
  (defun system-source-registry-directory (&key (direction :input))
225
    (find-preferred-file (system-config-pathnames *source-registry-directory*)
226
                         :direction direction))
227 228 229
  (defun environment-source-registry ()
    (getenv "CL_SOURCE_REGISTRY"))

230 231 232

  ;;; Process the source-registry configuration

233
  (defgeneric process-source-registry (spec &key inherit register))
234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258

  (defun* (inherit-source-registry) (inherit &key register)
    (when inherit
      (process-source-registry (first inherit) :register register :inherit (rest inherit))))

  (defun* (process-source-registry-directive) (directive &key inherit register)
    (destructuring-bind (kw &rest rest) (if (consp directive) directive (list directive))
      (ecase kw
        ((:include)
         (destructuring-bind (pathname) rest
           (process-source-registry (resolve-location pathname) :inherit nil :register register)))
        ((:directory)
         (destructuring-bind (pathname) rest
           (when pathname
             (funcall register (resolve-location pathname :ensure-directory t)))))
        ((:tree)
         (destructuring-bind (pathname) rest
           (when pathname
             (funcall register (resolve-location pathname :ensure-directory t)
                      :recurse t :exclude *source-registry-exclusions*))))
        ((:exclude)
         (setf *source-registry-exclusions* rest))
        ((:also-exclude)
         (appendf *source-registry-exclusions* rest))
        ((:default-registry)
259 260
         (inherit-source-registry
          '(default-user-source-registry default-system-source-registry) :register register))
261 262 263 264 265 266 267 268
        ((:inherit-configuration)
         (inherit-source-registry inherit :register register))
        ((:ignore-inherited-configuration)
         nil)))
    nil)

  (defmethod process-source-registry ((x symbol) &key inherit register)
    (process-source-registry (funcall x) :inherit inherit :register register))
269
  (defmethod process-source-registry ((pathname pathname) &key inherit register)
270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290
    (cond
      ((directory-pathname-p pathname)
       (let ((*here-directory* (resolve-symlinks* pathname)))
         (process-source-registry (validate-source-registry-directory pathname)
                                  :inherit inherit :register register)))
      ((probe-file* pathname :truename *resolve-symlinks*)
       (let ((*here-directory* (pathname-directory-pathname pathname)))
         (process-source-registry (validate-source-registry-file pathname)
                                  :inherit inherit :register register)))
      (t
       (inherit-source-registry inherit :register register))))
  (defmethod process-source-registry ((string string) &key inherit register)
    (process-source-registry (parse-source-registry-string string)
                             :inherit inherit :register register))
  (defmethod process-source-registry ((x null) &key inherit register)
    (inherit-source-registry inherit :register register))
  (defmethod process-source-registry ((form cons) &key inherit register)
    (let ((*source-registry-exclusions* *default-source-registry-exclusions*))
      (dolist (directive (cdr (validate-source-registry-form form)))
        (process-source-registry-directive directive :inherit inherit :register register))))

291 292

  ;; Flatten the user-provided configuration into an ordered list of directories and trees
293
  (defun flatten-source-registry (&optional (parameter *source-registry-parameter*))
294 295 296 297 298 299 300 301 302 303 304 305
    (remove-duplicates
     (while-collecting (collect)
       (with-pathname-defaults () ;; be location-independent
         (inherit-source-registry
          `(wrapping-source-registry
            ,parameter
            ,@*default-source-registries*)
          :register #'(lambda (directory &key recurse exclude)
                        (collect (list directory :recurse recurse :exclude exclude))))))
     :test 'equal :from-end t))

  ;; Will read the configuration and initialize all internal variables.
306 307
  (defun compute-source-registry (&optional (parameter *source-registry-parameter*)
                                    (registry *source-registry*))
308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337
    (dolist (entry (flatten-source-registry parameter))
      (destructuring-bind (directory &key recurse exclude) entry
        (let* ((h (make-hash-table :test 'equal))) ; table to detect duplicates
          (register-asd-directory
           directory :recurse recurse :exclude exclude :collect
           #'(lambda (asd)
               (let* ((name (pathname-name asd))
                      (name (if (typep asd 'logical-pathname)
                                ;; logical pathnames are upper-case,
                                ;; at least in the CLHS and on SBCL,
                                ;; yet (coerce-name :foo) is lower-case.
                                ;; won't work well with (load-system "Foo")
                                ;; instead of (load-system 'foo)
                                (string-downcase name)
                                name)))
                 (cond
                   ((gethash name registry) ; already shadowed by something else
                    nil)
                   ((gethash name h) ; conflict at current level
                    (when *verbose-out*
                      (warn (compatfmt "~@<In source-registry entry ~A~@[/~*~] ~
                                found several entries for ~A - picking ~S over ~S~:>")
                            directory recurse name (gethash name h) asd)))
                   (t
                    (setf (gethash name registry) asd)
                    (setf (gethash name h) asd))))))
          h)))
    (values))

  (defun initialize-source-registry (&optional (parameter *source-registry-parameter*))
338
    ;; Record the parameter used to configure the registry
339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362
    (setf *source-registry-parameter* parameter)
    ;; Clear the previous registry database:
    (setf *source-registry* (make-hash-table :test 'equal))
    ;; Do it!
    (compute-source-registry parameter))

  ;; Checks an initial variable to see whether the state is initialized
  ;; or cleared. In the former case, return current configuration; in
  ;; the latter, initialize.  ASDF will call this function at the start
  ;; of (asdf:find-system) to make sure the source registry is initialized.
  ;; However, it will do so *without* a parameter, at which point it
  ;; will be too late to provide a parameter to this function, though
  ;; you may override the configuration explicitly by calling
  ;; initialize-source-registry directly with your parameter.
  (defun ensure-source-registry (&optional parameter)
    (unless (source-registry-initialized-p)
      (initialize-source-registry parameter))
    (values))

  (defun sysdef-source-registry-search (system)
    (ensure-source-registry)
    (values (gethash (primary-system-name system) *source-registry*))))