Skip to content
Snippets Groups Projects
insts.lisp 83 KiB
Newer Older
ram's avatar
ram committed
;;; -*- Mode: LISP; Syntax: Common-Lisp; Base: 10; Package: x86 -*-
;;;
;;; **********************************************************************
;;; This code was written as part of the CMU Common Lisp project at
;;; Carnegie Mellon University, and has been placed in the public domain.
;;; If you want to use this code or any part of CMU Common Lisp, please contact
;;; Scott Fahlman or slisp-group@cs.cmu.edu.
;;;
(ext:file-comment
  "$Header: /Volumes/share2/src/cmucl/cvs2git/cvsroot/src/compiler/x86/insts.lisp,v 1.20 2000/04/21 20:30:40 dtc Exp $")
ram's avatar
ram committed
;;;
;;; **********************************************************************
;;;
;;; Description of the x86 instruction set, for 80386 and above.
;;;
;;; Written by William Lott
;;;
;;; Debugged by Paul F. Werkowski Spring/Summer 1995.
;;; Debugging and enhancements by Douglas Crosher 1996, 1997, 1998.
ram's avatar
ram committed
;;;

(in-package :x86)

(use-package :new-assem)

(def-assembler-params
  :scheduler-p nil)

(disassem:set-disassem-params :instruction-alignment 8)



;;;; Primitive emitters.

(define-emitter emit-word 16
  (byte 16 0))

(define-emitter emit-dword 32
  (byte 32 0))

(define-emitter emit-byte-with-reg 8
  (byte 5 3) (byte 3 0))

(define-emitter emit-mod-reg-r/m-byte 8
  (byte 2 6) (byte 3 3) (byte 3 0))

(define-emitter emit-sib-byte 8
  (byte 2 6) (byte 3 3) (byte 3 0))



;;;; Fixup emitters.

(defun emit-absolute-fixup (segment fixup)
  (note-fixup segment :absolute fixup)
  (let ((offset (fixup-offset fixup)))
    (if (label-p offset)
	(emit-back-patch segment 4
			 #'(lambda (segment posn)
			     (declare (ignore posn))
			     (emit-dword segment
					 (- (+ (component-header-length)
					       (or (label-position offset) 0) )
					    other-pointer-type))))
	(emit-dword segment (or offset 0)))))

(defun emit-relative-fixup (segment fixup)
  (note-fixup segment :relative fixup)
  (emit-dword segment (or (fixup-offset fixup) 0)))



;;;; The effective-address (ea) structure.

(defun reg-tn-encoding (tn)
  (declare (type tn tn))
  (assert (eq (sb-name (sc-sb (tn-sc tn))) 'registers))
  (let ((offset (tn-offset tn)))
    (logior (ash (logand offset 1) 2)
	    (ash offset -1))))

(defstruct (ea
	    (:constructor make-ea (size &key base index scale disp))
	    (:print-function %print-ea))
  (size nil :type (member :byte :word :dword))
  (base nil :type (or tn null))
  (index nil :type (or tn null))
  (scale 1 :type (member 1 2 4 8))
  (disp 0 :type (or (signed-byte 32) fixup)))

(defun %print-ea (ea stream depth)
  (declare (ignore depth))
  (cond ((or *print-escape* *print-readably*)
	 (print-unreadable-object (ea stream :type t)
	   (format stream
		   "~S~@[ base=~S~]~@[ index=~S~]~@[ scale=~S~]~@[ disp=~S~]"
		   (ea-size ea)
		   (ea-base ea)
		   (ea-index ea)
		   (let ((scale (ea-scale ea)))
		     (if (= scale 1) nil scale))
		   (ea-disp ea))))
	(t
	 (format stream "~A PTR [" (symbol-name (ea-size ea)))
	 (when (ea-base ea)
	   (write-string (x86-location-print-name (ea-base ea)) stream)
ram's avatar
ram committed
	   (when (ea-index ea)
	     (write-string "+" stream)))
	 (when (ea-index ea)
	   (write-string (x86-location-print-name (ea-index ea)) stream))
ram's avatar
ram committed
111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486
	 (unless (= (ea-scale ea) 1)
	   (format stream "*~A" (ea-scale ea)))
	 (typecase (ea-disp ea)
	   (null)
	   (integer
	    (format stream "~@D" (ea-disp ea)))
	   (t
	    (format stream "+~A" (ea-disp ea))))
	 (write-char #\] stream))))

(defun emit-ea (segment thing reg &optional allow-constants)
  (etypecase thing
    (tn
     (ecase (sb-name (sc-sb (tn-sc thing)))
       (registers
	(emit-mod-reg-r/m-byte segment #b11 reg (reg-tn-encoding thing)))
       (stack
	;; Convert stack tns into an index off of EBP.
	(let ((disp (- (* (1+ (tn-offset thing)) word-bytes))))
	  (cond ((< -128 disp 127)
		 (emit-mod-reg-r/m-byte segment #b01 reg #b101)
		 (emit-byte segment disp))
		(t
		 (emit-mod-reg-r/m-byte segment #b10 reg #b101)
		 (emit-dword segment disp)))))
       (constant
	(unless allow-constants
	  (error
	   "Constant TNs can only be directly used in MOV, PUSH, and CMP."))
	(emit-mod-reg-r/m-byte segment #b00 reg #b101)
	(emit-absolute-fixup segment
			     (make-fixup nil
					 :code-object
					 (- (* (tn-offset thing) word-bytes)
					    other-pointer-type))))))
    (ea
     (let* ((base (ea-base thing))
	    (index (ea-index thing))
	    (scale (ea-scale thing))
	    (disp (ea-disp thing))
	    (mod (cond ((or (null base)
			    (and (eql disp 0)
				 (not (= (reg-tn-encoding base) #b101))))
			#b00)
		       ((and (fixnump disp) (<= -128 disp 127))
			#b01)
		       (t
			#b10)))
	    (r/m (cond (index #b100)
		       ((null base) #b101)
		       (t (reg-tn-encoding base)))))
       (emit-mod-reg-r/m-byte segment mod reg r/m)
       (when (= r/m #b100)
	 (let ((ss (1- (integer-length scale)))
	       (index (if (null index)
			  #b100
			  (let ((index (reg-tn-encoding index)))
			    (if (= index #b100)
				(error "Can't index off of ESP")
				index))))
	       (base (if (null base)
			 #b101
			 (reg-tn-encoding base))))
	   (emit-sib-byte segment ss index base)))
       (cond ((= mod #b01)
	      (emit-byte segment disp))
	     ((or (= mod #b10) (null base))
	      (if (fixup-p disp)
		  (emit-absolute-fixup segment disp)
		  (emit-dword segment disp))))))
    (fixup
     (emit-mod-reg-r/m-byte segment #b00 reg #b101)
     (emit-absolute-fixup segment thing))))

(defun fp-reg-tn-p (thing)
  (and (tn-p thing)
       (eq (sb-name (sc-sb (tn-sc thing))) 'float-registers)))

;;;
;;; like the above, but for fp-instructions--jrd
;;;
(defun emit-fp-op (segment thing op)
  (if (fp-reg-tn-p thing)
      (emit-byte segment (dpb op (byte 3 3) (dpb (tn-offset thing)
						 (byte 3 0)
						 #b11000000)))
    (emit-ea segment thing op)))

(defun byte-reg-p (thing)
  (and (tn-p thing)
       (eq (sb-name (sc-sb (tn-sc thing))) 'registers)
       (member (sc-name (tn-sc thing)) byte-sc-names)
       t))

(defun byte-ea-p (thing)
  (typecase thing
    (ea (eq (ea-size thing) :byte))
    (tn
     (and (member (sc-name (tn-sc thing)) byte-sc-names) t))
    (t nil)))

(defun word-reg-p (thing)
  (and (tn-p thing)
       (eq (sb-name (sc-sb (tn-sc thing))) 'registers)
       (member (sc-name (tn-sc thing)) word-sc-names)
       t))

(defun word-ea-p (thing)
  (typecase thing
    (ea (eq (ea-size thing) :word))
    (tn (and (member (sc-name (tn-sc thing)) word-sc-names) t))
    (t nil)))

(defun dword-reg-p (thing)
  (and (tn-p thing)
       (eq (sb-name (sc-sb (tn-sc thing))) 'registers)
       (member (sc-name (tn-sc thing)) dword-sc-names)
       t))

(defun dword-ea-p (thing)
  (typecase thing
    (ea (eq (ea-size thing) :dword))
    (tn
     (and (member (sc-name (tn-sc thing)) dword-sc-names) t))
    (t nil)))

(defun register-p (thing)
  (and (tn-p thing)
       (eq (sb-name (sc-sb (tn-sc thing))) 'registers)))

(defun accumulator-p (thing)
  (and (register-p thing)
       (= (tn-offset thing) 0)))

(eval-when (compile load eval)
(defconstant conditions
  '((:o . 0)
    (:no . 1)
    (:b . 2) (:nae . 2) (:c . 2)
    (:nb . 3) (:ae . 3) (:nc . 3)
    (:eq . 4) (:e . 4) (:z . 4)
    (:ne . 5) (:nz . 5)
    (:be . 6) (:na . 6)
    (:nbe . 7) (:a . 7)
    (:s . 8)
    (:ns . 9)
    (:p . 10) (:pe . 10)
    (:np . 11) (:po . 11)
    (:l . 12) (:nge . 12)
    (:nl . 13) (:ge . 13)
    (:le . 14) (:ng . 14)
    (:nle . 15) (:g . 15)))

(defun conditional-opcode (condition)
  (cdr (assoc condition conditions :test #'eq))))



;;;; Utilities.

#-lispworks3
(defconstant operand-size-prefix-byte #b01100110)

#+lispworks3
(eval-when (compile load eval)
  (defconstant operand-size-prefix-byte #b01100110))

(defparameter *default-operand-size* :dword)

(defun maybe-emit-operand-size-prefix (segment size)
  (unless (or (eq size :byte) (eq size *default-operand-size*))
    (emit-byte segment operand-size-prefix-byte)))

(defun operand-size (thing)
  (typecase thing
    (tn
     (case (sc-name (tn-sc thing))
       (#.dword-sc-names
	:dword)
       (#.word-sc-names
	:word)
       (#.byte-sc-names
	:byte)
       ;; added by jrd.  float-registers is a separate size (?)
       (#.float-sc-names
	:float)
       (#.double-sc-names
	:double)
       (t
	(error "Can't tell the size of ~S ~S" thing (sc-name (tn-sc thing))))))
    (ea
     (ea-size thing))
    (t
     nil)))

(defun matching-operand-size (dst src)
  (let ((dst-size (operand-size dst))
	(src-size (operand-size src)))
    (if dst-size
	(if src-size
	    (if (eq dst-size src-size)
		dst-size
		(error "Size mismatch: ~S is a ~S and ~S is a ~S"
		       dst dst-size src src-size))
	    dst-size)
	(if src-size
	    src-size
	    (error "Can't tell the size of either ~S or ~S."
		   dst src)))))

(defun emit-sized-immediate (segment size value)
  (ecase size
    (:byte
     (emit-byte segment value))
    (:word
     (emit-word segment value))
    (:dword
     (emit-dword segment value))))



;;;; Disassembler support stuff.

(deftype reg () '(unsigned-byte 3))  
#+cross-compiler
(lisp:deftype reg () '(unsigned-byte 3))

(eval-when (compile eval load)

(defparameter *default-address-size*
  ;; Actually, :dword is the only one really supported.
  :dword)

(defparameter byte-reg-names
  #(al cl dl bl ah ch dh bh))
(defparameter word-reg-names
  #(ax cx dx bx sp bp si di))
(defparameter dword-reg-names
  #(eax ecx edx ebx esp ebp esi edi))

(defun print-reg-with-width (value width stream dstate)
  (declare (ignore dstate))
  (princ (aref (ecase width
		 (:byte byte-reg-names)
		 (:word word-reg-names)
		 (:dword dword-reg-names))
	       value)
	 stream)
  ;; plus should do some source-var notes
  )

(defun print-reg (value stream dstate)
  (declare (type reg value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (print-reg-with-width value
			(disassem:dstate-get-prop dstate 'width)
			stream
			dstate))

(defun print-word-reg (value stream dstate)
  (declare (type reg value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (print-reg-with-width value
			(or (disassem:dstate-get-prop dstate 'word-width)
			    *default-operand-size*)
			stream
			dstate))

(defun print-byte-reg (value stream dstate)
  (declare (type reg value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (print-reg-with-width value :byte stream dstate))

(defun print-addr-reg (value stream dstate)
  (declare (type reg value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (print-reg-with-width value *default-address-size* stream dstate))

;;; Value is a list of (BASE-REG OFFSET INDEX-REG INDEX-SCALE)
(defun print-mem-access (value stream print-size-p dstate)
  (declare (type list value)
	   (type stream stream)
	   (type (member t nil) print-size-p)
	   (type disassem:disassem-state dstate))
  (when print-size-p
    (princ (disassem:dstate-get-prop dstate 'width) stream)
    (princ '| PTR | stream))
  (write-char #\[ stream)
  (let ((firstp t))
    (macrolet ((pel ((var val) &body body)
		 ;; Print an element of the address, maybe with
		 ;; a leading separator.
		 `(let ((,var ,val))
		    (when ,var
		      (unless firstp
			(write-char #\+ stream))
		      ,@body
		      (setq firstp nil)))))
      (pel (base-reg (first value))
	(print-addr-reg base-reg stream dstate))
      (pel (index-reg (third value))
	(print-addr-reg index-reg stream dstate)
	(let ((index-scale (fourth value)))
	  (when (and index-scale (not (= index-scale 1)))
	    (write-char #\* stream)
	    (princ index-scale stream))))
      (let ((offset (second value)))
	(when (and offset (or firstp (not (zerop offset))))
	  (unless (or firstp (minusp offset))
	    (write-char #\+ stream))
	  (if firstp
	      (disassem:princ16 offset stream)
	      (princ offset stream))))))
  (write-char #\] stream))

(defun print-reg/mem (value stream dstate)
  (declare (type (or list reg) value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (if (typep value 'reg)
      (print-reg value stream dstate)
      (print-mem-access value stream nil dstate)))

;; Same as print-reg/mem, but prints an explicit size indicator for
;; memory references.
(defun print-sized-reg/mem (value stream dstate)
  (declare (type (or list reg) value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (if (typep value 'reg)
      (print-reg value stream dstate)
      (print-mem-access value stream t dstate)))

(defun print-byte-reg/mem (value stream dstate)
  (declare (type (or list reg) value)
	   (type stream stream)
	   (type disassem:disassem-state dstate))
  (if (typep value 'reg)
      (print-byte-reg value stream dstate)
      (print-mem-access value stream t dstate)))

(defun print-label (value stream dstate)
  (declare (ignore dstate))
  (disassem:princ16 value stream))

;;; Returns either an integer, meaning a register, or a list of
;;; (BASE-REG OFFSET INDEX-REG INDEX-SCALE), where any component
;;; may be missing or nil to indicate that it's not used or has the
;;; obvious default value (e.g., 1 for the index-scale).
(defun prefilter-reg/mem (value dstate)
  (declare (type list value)
	   (type disassem:disassem-state dstate))
  (let ((mod (car value))
	(r/m (cadr value)))
    (declare (type (unsigned-byte 2) mod)
	     (type (unsigned-byte 3) r/m))
    (cond ((= mod #b11)
	   ;; registers
	   r/m)
	  ((= r/m #b100)
	   ;; sib byte
	   (let ((sib (disassem:read-suffix 8 dstate)))
	     (declare (type (unsigned-byte 8) sib))
	     (let ((base-reg (ldb (byte 3 0) sib))
		   (index-reg (ldb (byte 3 3) sib))
		   (index-scale (ldb (byte 2 6) sib)))
	       (declare (type (unsigned-byte 3) base-reg index-reg)
			(type (unsigned-byte 2) index-scale))
	       (let* ((offset
		       (case mod
			 (#b00
			  (if (= base-reg #b101)
			      (disassem:read-signed-suffix 32 dstate)
ram's avatar
ram committed
			      nil))
			 (#b01
			  (disassem:read-signed-suffix 8 dstate))
			 (#b10
			  (disassem:read-signed-suffix 32 dstate)))))
ram's avatar
ram committed
		 (list (if (and (= mod #b00) (= base-reg #b101)) nil base-reg)
		       offset
		       (if (= index-reg #b100) nil index-reg)
		       (ash 1 index-scale))))))
	  ((and (= mod #b00) (= r/m #b101))
	   (list nil (disassem:read-signed-suffix 32 dstate)) )
ram's avatar
ram committed
	  ((= mod #b00)
	   (list r/m))
	  ((= mod #b01)
	   (list r/m (disassem:read-signed-suffix 8 dstate)))
	  (t				; (= mod #b10)
	   (list r/m (disassem:read-signed-suffix 32 dstate))))))
ram's avatar
ram committed


;;; This is a sort of bogus prefilter that just
;;; stores the info globally for other people to use; it
;;; probably never gets printed.
(defun prefilter-width (value dstate)
  (setf (disassem:dstate-get-prop dstate 'width)
	(if (zerop value)
	    :byte
	    (let ((word-width
		   ;; set by a prefix instruction
		   (or (disassem:dstate-get-prop dstate 'word-width)
		       *default-operand-size*)))
	      (when (not (eql word-width *default-operand-size*))
		;; reset it
		(setf (disassem:dstate-get-prop dstate 'word-width)
		      *default-operand-size*))
	      word-width))))

(defun offset-next (value dstate)
  (declare (type integer value)
ram's avatar
ram committed
	   (type disassem:disassem-state dstate))
  (+ (disassem:dstate-next-addr dstate) value))
ram's avatar
ram committed

(defun read-address (value dstate)
  (declare (ignore value))		; always nil anyway
  (disassem:read-suffix (width-bits *default-address-size*) dstate))

(defun width-bits (width)
  (ecase width
    (:byte 8)
    (:word 16)
    (:dword 32)
    (:float 32)
    (:double 64)))

); eval-when


;;;; Disassembler argument types.

(disassem:define-argument-type accum
  :printer #'(lambda (value stream dstate)
	       (declare (ignore value)
			(type stream stream)
			(type disassem:disassem-state dstate))
	       (print-reg 0 stream dstate))
  )

(disassem:define-argument-type word-accum
  :printer #'(lambda (value stream dstate)
	       (declare (ignore value)
			(type stream stream)
			(type disassem:disassem-state dstate))
	       (print-word-reg 0 stream dstate))
  )

(disassem:define-argument-type reg
  :printer #'print-reg)

(disassem:define-argument-type addr-reg
  :printer #'print-addr-reg)

(disassem:define-argument-type word-reg
  :printer #'print-word-reg)

(disassem:define-argument-type imm-addr
  :prefilter #'read-address
  :printer #'print-label)

(disassem:define-argument-type imm-data
  :prefilter #'(lambda (value dstate)
		 (declare (ignore value)) ; always nil anyway
		 (disassem:read-suffix
		  (width-bits (disassem:dstate-get-prop dstate 'width))
		  dstate))
  )

(disassem:define-argument-type signed-imm-data
  :prefilter #'(lambda (value dstate)
		 (declare (ignore value)) ; always nil anyway
		 (let ((width (disassem:dstate-get-prop dstate 'width)))
		   (disassem:read-signed-suffix (width-bits width) dstate)))
  )

(disassem:define-argument-type signed-imm-byte
  :prefilter #'(lambda (value dstate)
		 (declare (ignore value)) ; always nil anyway
		 (disassem:read-signed-suffix 8 dstate)))

(disassem:define-argument-type signed-imm-dword
  :prefilter #'(lambda (value dstate)
		 (declare (ignore value))		; always nil anyway
		 (disassem:read-signed-suffix 32 dstate)))
ram's avatar
ram committed

(disassem:define-argument-type imm-word
  :prefilter #'(lambda (value dstate)
		 (declare (ignore value)) ; always nil anyway
		 (let ((width
			(or (disassem:dstate-get-prop dstate 'word-width)
			    *default-operand-size*)))
		   (disassem:read-suffix (width-bits width) dstate))))

;;; Needed for the ret imm16 instruction
(disassem:define-argument-type imm-word-16
  :prefilter #'(lambda (value dstate)
		 (declare (ignore value)) ; always nil anyway
		 (disassem:read-suffix 16 dstate)))

(disassem:define-argument-type reg/mem
  :prefilter #'prefilter-reg/mem
  :printer #'print-reg/mem)
(disassem:define-argument-type sized-reg/mem
  ;; Same as reg/mem, but prints an explicit size indicator for
  ;; memory references.
  :prefilter #'prefilter-reg/mem
  :printer #'print-sized-reg/mem)
(disassem:define-argument-type byte-reg/mem
  :prefilter #'prefilter-reg/mem
  :printer #'print-byte-reg/mem)

;;;
;;; added by jrd
;;;
(eval-when (compile load eval)
(defun print-fp-reg (value stream dstate)
  (declare (ignore dstate))
  (format stream "FR~D" value))

(defun prefilter-fp-reg (value dstate)
  ;; just return it
  (declare (ignore dstate))
  value)
)
(disassem:define-argument-type fp-reg
			       :prefilter #'prefilter-fp-reg
			       :printer #'print-fp-reg)

(disassem:define-argument-type width
  :prefilter #'prefilter-width
  :printer #'(lambda (value stream dstate)
	       (if ;; (zerop value)
		   (or (null value) (and (numberp value) (zerop value)))	; zzz jrd
		   (princ 'b stream)
		   (let ((word-width
			  ;; set by a prefix instruction
			  (or (disassem:dstate-get-prop dstate 'word-width)
			      *default-operand-size*)))
		     (princ (schar (symbol-name word-width) 0) stream)))))


;;;; Disassembler instruction formats.

(eval-when (compile eval)
  (defun swap-if (direction field1 separator field2)
    `(:if (,direction :constant 0)
	  (,field1 ,separator ,field2)
	  (,field2 ,separator ,field1))))

(disassem:define-instruction-format (byte 8 :default-printer '(:name))
  (op    :field (byte 8 0))
  ;; optional fields
  (accum :type 'accum)
  (imm))

(disassem:define-instruction-format (simple 8)
  (op    :field (byte 7 1))
  (width :field (byte 1 0) :type 'width)
  ;; optional fields
  (accum :type 'accum)
  (imm))

;;; Same as simple, but with direction bit
(disassem:define-instruction-format (simple-dir 8 :include 'simple)
  (op :field (byte 6 2))
  (dir :field (byte 1 1)))

;;; Same as simple, but with the immediate value occuring by default,
;;; and with an appropiate printer.
(disassem:define-instruction-format (accum-imm 8
				     :include 'simple
				     :default-printer '(:name
							:tab accum ", " imm))
  (imm :type 'imm-data))

(disassem:define-instruction-format (reg-no-width 8
				     :default-printer '(:name :tab reg))
  (op	 :field (byte 5 3))
  (reg   :field (byte 3 0) :type 'word-reg)
  ;; optional fields
  (accum :type 'word-accum)
  (imm))

;;; adds a width field to reg-no-width
(disassem:define-instruction-format (reg 8 :default-printer '(:name :tab reg))
  (op    :field (byte 4 4))
  (width :field (byte 1 3) :type 'width)
  (reg   :field (byte 3 0) :type 'reg)
  ;; optional fields
  (accum :type 'accum)
  (imm)
  )

;;; Same as reg, but with direction bit
(disassem:define-instruction-format (reg-dir 8 :include 'reg)
  (op  :field (byte 3 5))
  (dir :field (byte 1 4)))

(disassem:define-instruction-format (two-bytes 16
				     :default-printer '(:name))
  (op :fields (list (byte 8 0) (byte 8 8))))

(disassem:define-instruction-format (reg-reg/mem 16
				     :default-printer
				        `(:name :tab reg ", " reg/mem))
  (op      :field (byte 7 1))
  (width   :field (byte 1 0)	:type 'width)
  (reg/mem :fields (list (byte 2 14) (byte 3 8))
	   			:type 'reg/mem)
  (reg     :field (byte 3 11)	:type 'reg)
  ;; optional fields
  (imm))

;;; same as reg-reg/mem, but with direction bit
(disassem:define-instruction-format (reg-reg/mem-dir 16
				     :include 'reg-reg/mem
				     :default-printer
				        `(:name
					  :tab
					  ,(swap-if 'dir 'reg/mem ", " 'reg)))
  (op  :field (byte 6 2))
  (dir :field (byte 1 1)))

;;; Same as reg-rem/mem, but uses the reg field as a second op code.
(disassem:define-instruction-format (reg/mem 16
				     :default-printer '(:name :tab reg/mem))
  (op      :fields (list (byte 7 1) (byte 3 11)))
  (width   :field (byte 1 0)	:type 'width)
  (reg/mem :fields (list (byte 2 14) (byte 3 8))
	   			:type 'sized-reg/mem)
  ;; optional fields
  (imm))

;;; Same as reg/mem, but with the immediate value occuring by default,
;;; and with an appropiate printer.
(disassem:define-instruction-format (reg/mem-imm 16
				     :include 'reg/mem
				     :default-printer
				        '(:name :tab reg/mem ", " imm))
  (reg/mem :type 'sized-reg/mem)
  (imm     :type 'imm-data))

;;; Same as reg/mem, but with using the accumulator in the default printer
(disassem:define-instruction-format
    (accum-reg/mem 16
     :include 'reg/mem :default-printer '(:name :tab accum ", " reg/mem))
  (reg/mem :type 'reg/mem)		; don't need a size
  (accum :type 'accum))

;;; Same as reg-reg/mem, but with a prefix of #b00001111
(disassem:define-instruction-format (ext-reg-reg/mem 24
				     :default-printer
				        `(:name :tab reg ", " reg/mem))
  (prefix  :field (byte 8 0)	:value #b00001111)
  (op      :field (byte 7 9))
  (width   :field (byte 1 8)	:type 'width)
  (reg/mem :fields (list (byte 2 22) (byte 3 16))
	   			:type 'reg/mem)
  (reg     :field (byte 3 19)	:type 'reg)
  ;; optional fields
  (imm))

;;; Same as reg/mem, but with a prefix of #b00001111
(disassem:define-instruction-format (ext-reg/mem 24
				     :default-printer '(:name :tab reg/mem))
  (prefix  :field (byte 8 0)	:value #b00001111)
  (op      :fields (list (byte 7 9) (byte 3 19)))
  (width   :field (byte 1 8)	:type 'width)
  (reg/mem :fields (list (byte 2 22) (byte 3 16))
	   			:type 'sized-reg/mem)
  ;; optional fields
  (imm))

;;; ----------------------------------------------------------------
;;; this section added by jrd, for fp instructions.  

;;; 
;;; regular fp inst to/from registers/memory
;;;
(disassem:define-instruction-format (floating-point 16 
				      :default-printer `(:name :tab reg/mem))
  (prefix :field (byte 5 3) :value #b11011)
  (op     :fields (list (byte 3 0) (byte 3 11)))
dtc's avatar
dtc committed
  (reg/mem :fields (list (byte 2 14) (byte 3 8)) :type 'reg/mem))
ram's avatar
ram committed

;;;
;;; fp insn to/from fp reg
;;;
(disassem:define-instruction-format (floating-point-fp 16 
				      :default-printer `(:name :tab fp-reg))
  (prefix :field (byte 5 3) :value #b11011)
  (suffix :field (byte 2 14) :value #b11)
  (op     :fields (list (byte 3 0) (byte 3 11)))
dtc's avatar
dtc committed
  (fp-reg :field (byte 3 8) :type 'fp-reg))
ram's avatar
ram committed

;;;
;;; fp insn to/from fp reg, with the reversed source/destination flag.
;;;
(disassem:define-instruction-format
 (floating-point-fp-d 16 
   :default-printer `(:name :tab ,(swap-if 'd "ST0" ", " 'fp-reg)))
  (prefix :field (byte 5 3) :value #b11011)
  (suffix :field (byte 2 14) :value #b11)
  (op     :fields (list (byte 2 0) (byte 3 11)))
  (d      :field (byte 1 2))
dtc's avatar
dtc committed
  (fp-reg :field (byte 3 8) :type 'fp-reg))
ram's avatar
ram committed


;;; pfw
;;; fp no operand isns
;;;
(disassem:define-instruction-format (floating-point-no 16
				      :default-printer '(:name))
  (prefix :field (byte 8  0) :value #b11011001)
  (suffix :field (byte 3 13) :value #b111)
  (op     :field (byte 5  8)))

dtc's avatar
dtc committed
(disassem:define-instruction-format (floating-point-3 16
				      :default-printer '(:name))
  (prefix :field (byte 5 3) :value #b11011)
  (suffix :field (byte 2 14) :value #b11)
  (op     :fields (list (byte 3 0) (byte 6 8))))

ram's avatar
ram committed
(disassem:define-instruction-format (floating-point-5 16
				      :default-printer '(:name))
  (prefix :field (byte 8  0) :value #b11011011)
  (suffix :field (byte 3 13) :value #b111)
  (op     :field (byte 5  8)))

(disassem:define-instruction-format (floating-point-st 16
				      :default-printer '(:name))
  (prefix :field (byte 8  0) :value #b11011111)
  (suffix :field (byte 3 13) :value #b111)
  (op     :field (byte 5  8)))


;;; ----------------------------------------------------------------


;;;; General Data Transfer

(eval-when (eval compile load)
  (defun toggle-word-width (chunk inst stream dstate)
    (declare (ignore chunk inst stream))
    (let ((ww (or (disassem:dstate-get-prop dstate 'word-width)
		  *default-operand-size*)))
      (setf (disassem:dstate-get-prop dstate 'word-width)
	    (ecase ww
	      (:word :dword)
	      (:dword :word))))))

;;; This isn't a really an instruction, but it's easier to deal with it this
;;; way.  We assume that it's actually used.
(define-instruction toggle-data-size (segment)
  (:printer byte ((op operand-size-prefix-byte))
	    nil				; don't actually print it
	    :control #'toggle-word-width))


(define-instruction mov (segment dst src)
  ;; immediate to register
  (:printer reg ((op #b1011) (imm nil :type 'imm-data))
	    '(:name :tab reg ", " imm))
  ;; absolute mem to/from accumulator
  (:printer simple-dir ((op #b101000) (imm nil :type 'imm-addr))
	    `(:name :tab ,(swap-if 'dir 'accum ", " '("[" imm "]"))))
  ;; register to/from register/memory
  (:printer reg-reg/mem-dir ((op #b100010)))
  ;; immediate to register/memory
  (:printer reg/mem-imm ((op '(#b1100011 #b000))))

  (:emitter
   (let ((size (matching-operand-size dst src)))
     (maybe-emit-operand-size-prefix segment size)
     (cond ((register-p dst)
	    (cond ((integerp src)
		   (emit-byte-with-reg segment
				       (if (eq size :byte)
					   #b10110
					   #b10111)
				       (reg-tn-encoding dst))
		   (emit-sized-immediate segment size src))
		  ((and (fixup-p src) (accumulator-p dst))
		   (emit-byte segment
			      (if (eq size :byte)
				  #b10100000
				  #b10100001))
		   (emit-absolute-fixup segment src))
		  (t
		   (emit-byte segment
			      (if (eq size :byte)
				  #b10001010
				  #b10001011))
		   (emit-ea segment src (reg-tn-encoding dst) t))))
	   ((and (fixup-p dst) (accumulator-p src))
	    (emit-byte segment (if (eq size :byte) #b10100010 #b10100011))
	    (emit-absolute-fixup segment dst))
	   ((integerp src)
	    (emit-byte segment (if (eq size :byte) #b11000110 #b11000111))
	    (emit-ea segment dst #b000)
	    (emit-sized-immediate segment size src))
	   ((register-p src)
	    (emit-byte segment (if (eq size :byte) #b10001000 #b10001001))
	    (emit-ea segment dst (reg-tn-encoding src)))
	   ((fixup-p src)
	    (assert (eq size :dword))
	    (emit-byte segment #b11000111)
	    (emit-ea segment dst #b000)
	    (emit-absolute-fixup segment src))
	   (t
	    (error "Bogus arguments to MOV: ~S ~S" dst src))))))

(defun emit-move-with-extension (segment dst src opcode)
  (assert (register-p dst))
  (let ((dst-size (operand-size dst))
	(src-size (operand-size src)))
    (ecase dst-size
      (:word
       (assert (eq src-size :byte))
       (maybe-emit-operand-size-prefix segment :word)
       (emit-byte segment #b00001111)
       (emit-byte segment opcode)
       (emit-ea segment src (reg-tn-encoding dst)))
      (:dword
       (ecase src-size
	 (:byte
	  (maybe-emit-operand-size-prefix segment :dword)
	  (emit-byte segment #b00001111)
	  (emit-byte segment opcode)
	  (emit-ea segment src (reg-tn-encoding dst)))
	 (:word
	  (emit-byte segment #b00001111)
	  (emit-byte segment (logior opcode 1))
	  (emit-ea segment src (reg-tn-encoding dst))))))))
	  
(define-instruction movsx (segment dst src)
  (:printer ext-reg-reg/mem ((op #b1011111) (reg nil :type 'word-reg)))
  (:emitter
   (emit-move-with-extension segment dst src #b10111110)))

(define-instruction movzx (segment dst src)
  (:printer ext-reg-reg/mem ((op #b1011011) (reg nil :type 'word-reg)))
  (:emitter
   (emit-move-with-extension segment dst src #b10110110)))

(define-instruction push (segment src)
  ;; Register.
  (:printer reg-no-width ((op #b01010)))
  ;; Register/Memory.
  (:printer reg/mem ((op '(#b1111111 #b110)) (width 1)))
  ;; Immediate.
  (:printer byte ((op #b01101010) (imm nil :type 'signed-imm-byte))
	    '(:name :tab imm))
  (:printer byte ((op #b01101000) (imm nil :type 'imm-word))
	    '(:name :tab imm))
  ;; ### Segment registers?

  (:emitter
   (cond ((integerp src)
	  (cond ((<= -128 src 127)
		 (emit-byte segment #b01101010)
		 (emit-byte segment src))
		(t
		 (emit-byte segment #b01101000)
		 (emit-dword segment src))))
	 ((fixup-p src)
	  ;; Interpret the fixup as an immediate dword to push
	  (emit-byte segment #b01101000)
	  (emit-absolute-fixup segment src))
	 (t
	  (let ((size (operand-size src)))
	    (assert (not (eq size :byte)))
	    (maybe-emit-operand-size-prefix segment size)
	    (cond ((register-p src)
		   (emit-byte-with-reg segment #b01010 (reg-tn-encoding src)))
		  (t
		   (emit-byte segment #b11111111)
		   (emit-ea segment src #b110 t))))))))

(define-instruction pusha (segment)
  (:printer byte ((op #b01100000)))
  (:emitter
   (emit-byte segment #b01100000)))

(define-instruction pop (segment dst)
  (:printer reg-no-width ((op #b01011)))